GAMBAS-BUCH 3.19.5

Dieses Steuerelement implementiert einen Dokumentenbetrachter.

Die Klasse ist erzeugbar. So erzeugen Sie ein neues DocumentView-Objekt:

  Dim hDocumentView As DocumentView
  hDocumentView = New DocumentView ( Parent As Container ) [ As "EventName" ]

Die Klasse DocumentView verfügt über diese Eigenschaften:

Tabelle 23.13.1.1 : Eigenschaften der Klasse DocumentView

Die Klasse DocumentView verfügt über diese wesentlichen Methoden:

Tabelle 23.13.2.1 : Methoden der Klasse DocumentView

Die Klasse DocumentView verfügt über diese Ereignisse:

Tabelle 23.13.3.1 : Ereignisse der Klasse DocumentView

Der Entwickler des Steuerelementes Fabien Bodard beschrieb die Anwendungsmöglichkeiten einer DocumentView so: Sie kann nicht nur PDF-Dokumente anzeigen, sondern eigentlich alles, was Sie möchten, solange es ein Dienstprogramm gibt, mit dem Sie den Inhalt rendern können. DocumentView liefert Ihnen 'Leinwände', auf denen Sie das zeichnen können, was Sie wollen. Es kann also alles Mögliche sein, solange Sie es mit der Funktion Paint.DrawImage() zeichnen können.

Eine typische Anwendung für das Steuerelement DocumentView ist die Anzeige von PDF-Dateien:

Abbildung 23.13.3.2.1: Anzeige eines PDF-Dokumentes (Ausschnitt)

Quelltext:

' Gambas class file
 
Private $PDF_Document As New PdfDocument
 
Public Sub Form_Open()
    btnOpen.SetFocus()
End
 
Public Sub btnOpen_Click()
  Dialog.Filter = ["*.pdf", "PDF-Files"]
  If Not Dialog.OpenFile() Then
     $PDF_Document.Open(Dialog.Path)
 '-- Setup the number of pages shown in the viewer. It enforce the layout event call
     DocumentView1.Count = $PDF_Document.Count
     DocumentView1.Refresh()
     Wait
  Else
     Return
  Endif
End
 
Public Sub DocumentView1_Layout(Page As Integer)
  DocumentView1.Layout.Width = $PDF_Document[Page + 1].Width
  DocumentView1.Layout.Height = $PDF_Document[Page + 1].Height
End
 
Public Sub DocumentView1_Draw(Page As Integer, Width As Integer, Height As Integer)
'-- Draw the pdf image
    Paint.DrawImage($PDF_Document[Page + 1].Image, 0, 0, Paint.Width, Paint.Height)
End
 
Public Sub DocumentView1_Zoom()
    $PDF_Document.Zoom = Last.Zoom
End
 
Public Sub Form_Resize()
    DocumentView1.Column = 1
    DocumentView1.Refresh()
    Wait
End
 
Public Sub btnClose_Click()
    FMain.Close()
End

Im zweiten Projekt wird jeder Bild-Inhalt auf ein separates Image – als Leinwand – gezeichnet und in der Größe angezeigt, die durch den Schieberegler im Bereich von 0% bis 200% für jede einzelne Seite vorgegeben wird:

Public Sub DocumentView1_Draw(Page As Integer, Width As Integer, Height As Integer)
    Paint.DrawImage($aImages[Page], 0, 0, Width, Height)
End

Dabei steht nicht die detaillierte Vorschau einzelner Bilder im Vordergrund, sondern die Übersicht zu allen Bildern im ausgewählten Verzeichnis:

Abbildung 23.13.3.3.1: Verkleinerte Anzeige von Bildern in einer DocumentView

Quelltext:

' Gambas class file
 
Private $sPath As String
Private $aImages As New Image[]
 
Public Sub Form_Open()
 
    lblMin.Text = sliderZoom.MinValue
    lblMax.Text = Str(sliderZoom.MaxValue) & "%"
 
    DocumentView1.Arrangement = Arrange.None
    DocumentView1.Columns = 0
    DocumentView1.Center = True
    DocumentView1.Spacing = 20
 
    sliderZoom.Value = 30
    DirBox1.Tooltip = "Select an image directory!"
    ChangePath()
 
End
 
Public Sub DirBox1_Change()
    $sPath = Last.Path
    ChangePath()
    sliderZoom.Value = 32
End
 
Public Sub ChangePath()
 
    Dim sFile As String
    Dim hImage As Image
 
    $aImages.Clear()
    For Each sFile In Dir($sPath, Null, gb.File)
        Select Case File.Ext(sFile)
          Case "png", "jpg"
            hImage = Image.Load($sPath &/ sFile)
            $aImages.Add(hImage)
        End Select
    Next
    DocumentView1.Count = $aImages.Count
End
 
Public Sub DocumentView1_Draw(Page As Integer, Width As Integer, Height As Integer)
    Paint.DrawImage($aImages[Page], 0, 0, Width, Height)
End
 
Public Sub DocumentView1_Layout(Page As Integer)
 
'-- Allow to define specific layout for items
'-- It is called before the drawing... so images need to be seen twice in this case
    DocumentView1.Layout.Width = $aImages[Page].W
    DocumentView1.Layout.Height = $aImages[Page].H
End
 
Public Sub DocumentView1_Zoom()
    DocumentView1.Refresh()
End
 
Public Sub sliderZoom_Change()
    DocumentView1.Zoom = sliderZoom.Value / 100
    lblMax.Text = Str(sliderZoom.Value) & "%"
End

Sie finden die Projekt-Archive für die beiden vorgestellten Projekte im Download-Bereich.