GAMBAS-BUCH 3.19.1

Das Steuerelement FileView (gb.form) zeigt Dateien in einem ausgewählten Verzeichnis an.

Ein FileView-Steuerelement kann erzeugt werden:

Dim hFileView As FileView

hFileView = New FileView ( Parent As Container ) As "EventName" 

Die Klasse verfügt für die Eigenschaft FileView.View über diese 4 Konstanten:

• Compact
• Detailed
• Normal
• Preview

Die Klasse FileView verfügt über diese Eigenschaften:

Tabelle 6.9.4.1.1 : Eigenschaften der Klasse FileView

Hinweise:

• Zugriff auf den Dateinamen zu einer ausgewählten Datei – Modus Single – im Projekt bekommen Sie, wenn Sie den Wert der Eigenschaft FileView.Current zum Beispiel in einer (Public-)Variablen sFileName = FileView.Current speichern. Zugriff auf die im Modus FileView.Multiple = True ausgewählten Dateien bekommen Sie zum Beispiel, wenn Sie die Liste der ausgewählten Dateinamen, gespeichert in der Eigenschaft FileView.Selection, in einer (Public-)Variablen vom Typ String-Array wie aFileNames = FileView.Selection abspeichern.
• Das ist ein Beispiel für ein Datei-Filter: FileView1.Filter = [„*.txt“, „*.png“, „*.pd*“, „*.jp*“, „*.xml“] .
• Dem Filter sollte im Quelltext die Instruktion Wait folgen, damit die Datei-Anzahl sofort aktualisiert wird.

Abbildung 6.9.4.1.1: Ausgewählte Datei in einer FileView

Abbildung 6.9.4.1.2: Liste der ausgewählten Dateien in einer FileView

Die Klasse FileView besitzt diese ausgewählten Methoden:

Tabelle 6.9.4.2.1 : Ausgewählte Methoden der Klasse FileView

Die Klasse FileView verfügt u.a. über folgende Ereignisse:

Tabelle 6.9.4.3.1 : Ereignisse der Klasse FileView

Der Quelltext zum Projekt setzt die o.a. Hinweise um:

' Gambas class file
 
Public sFileName As String
Public aFileNames As String[]
 
Public Sub Form_Open()
 
  FMain.Resizable = False
  DirBox1.Value = "/home/hans/BildTon" ' (Start-)Folder
 
  FileView1.Dir = DirBox1.Value
  FileView1.IconSize = 32 ' Default-Value = 32
  FileView1.ShowPreview = True
  FileView1.ShowHidden = True
  FileView1.Background = &HC3DDFF
  FileView1.Foreground = Color.DarkGreen
  FileView1.Mode = Select.Single
 
  FileView1.Filter = ["*.txt", "*.png", "*.pd*", "*.jp*", "*.xml"] 
  Wait
 
  btnShowFileListContent.Enabled = False
 
End
 
Public Sub FileView1_Click()
 
  Dim sFileDir, sFilePath As String
 
  sFileName = FileView1.Current
  sFileDir = FileView1.Dir
  sFilePath = sFileDir &/ sFileName
 
  lblFileName.Text = Subst("&1 &2 &3", ("Filename"), ":", sFileName)
 
End
 
Public Sub FileView1_Select()  
  If FileView1.Current Then
     Print Subst("&1 '&2' &3", ("The file"), FileView1.Current, ("has been selected."))
  Endif
End
 
Public Sub DirBox1_Click()
  FileView1.Dir = DirBox1.Value
End
 
Public Sub btnSetMultiple_Click()
 
  If FileView1.Mode = Select.Single Then ' The default-value is "Single"
     FileView1.Mode = Select.Multiple
     btnSetMultiple.Caption = "Set file selection to single"
     btnShowFileListContent.Enabled = True
  Else
     FileView1.Mode = Select.Single
     btnSetMultiple.Caption = "Set file selection to multiple"
     btnShowFileListContent.Enabled = False
  Endif
 
End
 
Public Sub btnShowFileListContent_Click()
 
  Dim sFile, sContent As String
 
  If FileView1.Mode = Select.Multiple Then
     If FileView1.Selection.Count > 0 Then 
        lblFileName.Text = ""
        aFileNames = FileView1.Selection
        For Each sFile In aFileNames
          sContent &= sFile & gb.Lf
        Next
        Message.Info("Selected files:<hr>" & sContent)
        FileView1.UnselectAll()
        FileView1.Mode = Select.Single
        btnSetMultiple.Caption = "Set file selection to multiple" 
        btnShowFileListContent.Enabled = False
     Endif 
  Endif
End